Condensed equipment lists for Final Fantasy IV, specifically the Super Nintendo release ("Final Fantasy II")

Replaying FF4 for the first time in many years, I searched the web for a refresher on the various equipment options and found myself bewildered at the profusion of releases. By the early '90s there were already three competing versions, and in the meantime there have been so many ports and reissues, each tinkering with the formula, that it was hard to find a source. Not that there aren't comprehensive guides on virtually every aspect of every version, but I was hoping for an at-a-glance reference to my version rather than an exhaustive collation. I decided to "quickly" dump the data I cared about from the ROM and got a little carried away.

This is a crude HTML rendition of the source document, ff2eq.txt, a fixed-width text file.

Who can equip what?

• Bows can be equipped by women and children and, uh, Edward, as well as Cecil after class change. All are right-handed, which means the arrows should go in the right hand and the bow in the left; otherwise it's less damage.
• Knives can be equipped by several characters: Kain, Rydia, Edward, Palom, Edge, and Cecil.
• Rods can be equipped by anyone with access to black magic.
• Staves can be equipped by anyone with access to white magic except that Cecil can't equip the more powerful ones (Power, Lunar, Life, or Silence).
• The unspecialized swords (Fire, Silver, and so on) can be equipped by Cecil or Kain.
• Axes can be equipped by Cecil, Kain, or Cid.
• The projectiles (shuriken, ninja stars, and the spoon) can't be equipped; they're just for throwing.

Who can equip what?

• Anyone can equip the Adamant armor.
• The Tiara and the Heroine robe can be equipped by women only.
• Shields, heavy armor, and gauntlets can be equipped by Cecil, Kain, or Cid. A few are reserved for Cecil alone, e.g., the Paladin and Crystal set. The Samurai series (except for the shield) is open to Edge, who can also wear the Iron and Silver gauntlets and (with Yang and Rydia) the Zeus gauntlet and the Strength Ring.
• Certain rings are off limits to Cecil, Kain, and Cid: Iron, Silver, Rune, and Diamond.
• There are three main classes of headgear, unfortunately all with the same icon: heavy helmets for Cecil, Kain, and Cid (Silver, Diamond, Dragoon); magical hats for mages (Gaea, Wizard); and light hats for anyone (from the Cap and Leather hat at the game's beginning to the Ribbon at its end, as well as the Headband, Bandanna, and even the Ninja hat).
• Similarly, some robes (Gaea, Wizard, Sorcerer) are just for mages. The White and Black robes are further specialized.

Item data begins at 0x79100 (no header). There are 96 weapons followed by 80 pieces of armor (some blank or unused).

Deathlike2's Item/Equipment Guide on GameFAQs

https://gamefaqs.gamespot.com/mobile/974825-final-fantasy-iv/faqs/79748

Also useful for spot checks was Inven's equipment spreadsheet linked from the Free Enterprise wiki:

https://wiki.ff4fe.com/doku.php?id=guides_resources

I don't expect to revisit it and haven't bothered to clean it up -- it was written in haste -- but here's the code for the table dump. The output will differ a bit from the above because I spent some time editing it to fit within 72 columns and to expand on special properties and custom resistances.

(use srfi.13)
(use gauche.uvector)

(define (main args)
  (cond
   ((not (length=? args 2))
    (print #"Usage: ~(sys-basename (car args)) ROMFILE"))
   (else
    (with-input-from-file (cadr args)
      (lambda ()
        (load-item-names)
        (load-spell-names)
        (weapon-table)
        (armor-table)))))
  0)

(define item-icon-codes (make-vector 176))
(define item-names (make-vector 176))
(define spell-names (make-vector 72))

(define (load-item-names)
  (port-seek (current-input-port) #x78000)
  (dotimes (i 176)
    (vector-set! item-icon-codes i (read-byte))
    (vector-set! item-names i (encode (read-bytevector 8)))))

;; Offsets assume an unheadered ROM file.

(define (encode v)
  (string-trim-right
   (list->string
    (map
     (cut alist-ref text-table <> eqv?)
     (u8vector->list v)))))

;; TEXT-TABLE and ICON-TABLE were taken from

;;     https://datacrystal.tcrf.net/wiki/Final_Fantasy_IV_(SNES)/TBL

;; They're defined at the end of this file.

(define (load-spell-names)
  (port-seek (current-input-port) #x78900)
  (dotimes (i 72)
    (read-byte)
    (vector-set! spell-names i (encode (read-bytevector 5)))))

(define (weapon-table)
  (port-seek (current-input-port) #x79100)
  (let loop ((i 0))
    (if (<= 96 i)
      'done
      (let* ((record (read-bytevector 8))
             (weapon-flags (u8vector-ref record 0)))
        (format
         #t
         "~a~a~a~a~a ~3@a ~a ~a~a~a~a~a\n"
         (if (logbit? 7 weapon-flags) "M" " ")
         (if (logbit? 6 weapon-flags) "T" " ")
         (if (logbit? 5 weapon-flags) "R" " ")
         (if (logbit? 0 weapon-flags) "C" " ")
         (if (logbit? 5 (u8vector-ref record 6)) "W" " ")
         (u8vector-ref record 1)
         (hit% (logand #x7F (u8vector-ref record 2)))
         (item-name i)
         (attribute (logand #x7F (u8vector-ref record 4)))
         (monster (u8vector-ref record 5))
         (spell (u8vector-ref record 3))
         (stat-summary (u8vector-ref record 7)))
        (loop (+ 1 i))))))

(define (hit% c) (if (zero? c) "   " (format "~a%" c)))

(define (item-name i)
  (let ((body (vector-ref item-names i))
        (icon (alist-ref icon-table (vector-ref item-icon-codes i))))
    (if (and icon (string-scan body icon))
      body
      (format "~a [~a]" body icon))))

(define (attribute n)
  (fmt " (~a)" (alist-ref element-table n eqv? "Cust.")))

;; ELEMENT-TABLE is defined below.  It was adapted from the highly
;; educational FFIV Disassembly project:

;;     https://github.com/everything8215/ff4

(define (fmt template value)
  (if (zero? (string-size value))
    ""
    (format template value)))

(define (spell n)
  (fmt " (use for ~a)" (vector-ref spell-names n "Custom")))

(define (monster c)
  (fmt
   " (bonus v. ~a)"
   (string-join
    (filter-map
     (lambda (b)
       (and (logbit? b c)
            (case b
              ((0) "Dragon")
              ((1) "Mech")
              ((2) "Lizard")
              ((3) "Spirit")
              ((4) "Giant")
              ((5) "Slime")
              ((6) "Mage")
              ((7) "Undead"))))
     '(7 6 5 4 3 2 1 0))
    ", ")))

(define (stat-summary c)
  (define (plus n) (case n ((0) 3) ((1 4 7) 5) ((2 5) 10) ((3 6) 15)))
  (define (minus n) (case n ((4) 5) ((5 7) 10) ((6) 15)))
  (define (stat n)
    (case n
      ((7) "Str")
      ((6) "Agil")
      ((5) "Vit")
      ((4) "Wis")
      ((3) "Will")))
  (let ((lo (bit-field c 0 3))
        (pos (filter (cut logbit? <> c) '(7 6 5 4 3)))
        (neg (if (logbit? 2 c)
               (remove (cut logbit? <> c) '(7 6 5 4 3))
               '())))
    (let ((spos (and (pair? pos) (string-join (map stat pos) "/")))
          (sneg (and (pair? neg) (string-join (map stat neg) "/"))))
      (cond ((and spos sneg)
             (format " ~a +~a, ~a -~a" spos (plus lo) sneg (minus lo)))
            (spos (format " ~a +~a" spos (plus lo)))
            (sneg (format " ~a -~a" sneg (minus lo)))
            (else "")))))

(define (armor-table)
  (port-seek (current-input-port) #x79400)
  (let loop ((i 96))
    (if (<= 176 i)
      'done
      (let1 record (read-bytevector 8)
        (format
         #t
         "~a ~3@a ~3@a ~2@a ~3@a ~a~a~a~a\n"
         (if (logbit? 7 (u8vector-ref record 0)) "M" " ")
         (u8vector-ref record 1)
         (hit% (logand #x7F (u8vector-ref record 2)))
         (u8vector-ref record 3)
         (hit% (logand #x7F (u8vector-ref record 0)))
         (item-name i)
         (attribute (logand #x7F (u8vector-ref record 4)))
         (monster (u8vector-ref record 5))
         (stat-summary (u8vector-ref record 7)))
        (loop (+ 1 i))))))

(define
  text-table
  '((#x42 . #\A)
    (#x43 . #\B)
    (#x44 . #\C)
    (#x45 . #\D)
    (#x46 . #\E)
    (#x47 . #\F)
    (#x48 . #\G)
    (#x49 . #\H)
    (#x4A . #\I)
    (#x4B . #\J)
    (#x4C . #\K)
    (#x4D . #\L)
    (#x4E . #\M)
    (#x4F . #\N)
    (#x50 . #\O)
    (#x51 . #\P)
    (#x52 . #\Q)
    (#x53 . #\R)
    (#x54 . #\S)
    (#x55 . #\T)
    (#x56 . #\U)
    (#x57 . #\V)
    (#x58 . #\W)
    (#x59 . #\X)
    (#x5A . #\Y)
    (#x5B . #\Z)
    (#x5C . #\a)
    (#x5D . #\b)
    (#x5E . #\c)
    (#x5F . #\d)
    (#x60 . #\e)
    (#x61 . #\f)
    (#x62 . #\g)
    (#x63 . #\h)
    (#x64 . #\i)
    (#x65 . #\j)
    (#x66 . #\k)
    (#x67 . #\l)
    (#x68 . #\m)
    (#x69 . #\n)
    (#x6A . #\o)
    (#x6B . #\p)
    (#x6C . #\q)
    (#x6D . #\r)
    (#x6E . #\s)
    (#x6F . #\t)
    (#x70 . #\u)
    (#x71 . #\v)
    (#x72 . #\w)
    (#x73 . #\x)
    (#x74 . #\y)
    (#x75 . #\z)
    (#x80 . #\0)
    (#x81 . #\1)
    (#x82 . #\2)
    (#x83 . #\3)
    (#x84 . #\4)
    (#x85 . #\5)
    (#x86 . #\6)
    (#x87 . #\7)
    (#x88 . #\8)
    (#x89 . #\9)
    (#xC0 . #\')
    (#xC1 . #\.)
    (#xC2 . #\-)
    (#xC3 . #\…)
    (#xC4 . #\!)
    (#xC5 . #\?)
    (#xC6 . #\%)
    (#xC7 . #\/)
    (#xC8 . #\:)
    (#xC9 . #\,)
    (#xFF . #\space)))

(define
  icon-table
  '((#x29 . "Claw")
    (#x2A . "Rod")
    (#x2B . "Staff")
    (#x2C . "Sword")
    (#x2D . "Sword")
    (#x2E . "Sword")
    (#x2F . "Spear")
    (#x30 . "Knife")
    (#x31 . "Katana")
    (#x32 . "Star")
    (#x33 . "Boomerang")
    (#x34 . "Axe")
    (#x35 . "Wrench")
    (#x36 . "Harp")
    (#x37 . "Bow")
    (#x38 . "Arrow")
    (#x39 . "Hammer")
    (#x3A . "Whip")
    (#x3B . "Shield")
    (#x3C . "Helmet")
    (#x3D . "Armor")
    (#x3E . "Glove")
    (#x7B . "Robe")
    (#x7C . "Ring")))

(define
  element-table
  '((0 . "")
    (1 . "Fire")
    (2 . "Ice")
    (3 . "Lit")
    (4 . "Dark")
    (5 . "White")
    (6 . "Wind")
    (7 . "Drain")
    (10 . "Bersk")
    (11 . "Charm")
    (12 . "Sleep")
    (13 . "Hold")
    (14 . "Float")
    (15 . "Curse")
    (16 . "Poison")
    (17 . "Blind")
    (18 . "Mute")
    (19 . "Pig")
    (20 . "Mini")
    (21 . "Toad")
    (22 . "Stone")
    (23 . "Death")))